小偷其实很简单，略懂asp都可以自己定制一个，但由于小偷调用远程文件，速度会比较慢，所以目前流行缓存小偷，入库小偷，生成html的小偷。
现在结合先锋海盗做谈谈静态小偷,都是一些很基础的东西。高手就不用看了
[quote]
<!--#include file=clsthief.asp-->
<%
dim myThief,list
set myThief=new clsThief
myThief.src="http://www.im286.com"
myThief.steal '开始偷窃
mythief.change"落伍","im286" '这里可以自己修改，只举个列子
list=myThief.value '获得偷取的内容
set myThief=nothing '释放对象
'这里页面信息已经获取，现在就是静态生成了
'asp两种方法生成文件。fso和adodb.stream.我用adodb.stream
sub SaveToFile(ByVal strBody,ByVal File)
Dim objStream
On Error Resume Next
Set objStream = Server.CreateObject("ADODB.Stream")
If Err.Number=-2147221005 Then
Response.Write "<div align='center'>非常遗憾,您的主机不支持ADODB.Stream,不能使用本程序</div>"
Err.Clear
Response.End
End If
With objStream
.Type = 2
.Open
.Charset = "GB2312"
.Position = objStream.Size
.WriteText = strBody
.SaveToFile Server.MapPath(File),2
.Close
End With
Set objStream = Nothing
End sub 'adodb.stream生成文件函数，strBody为生成内容，File为生成文件名

call savetofile (list,"index.html")
%>[/quote]

到这里首页生成完毕，(后面的页面一般可以把“index.htM”改为 ID&".HTML"
当然，一般小偷只截取中间部分，首尾一般用include file 调用，所以还要读取首尾文件
这里是用adodb读取文件的函数，然后用savetofile函数生成

[quote]
Function LoadFile(ByVal File) '文件地址
Dim objStream
On Error Resume Next
Set objStream = Server.CreateObject("ADODB.Stream")
If Err.Number=-2147221005 Then
Response.Write " 非常遗憾,您的主机不支持ADODB.Stream,不能使用本程序"
Err.Clear
Response.End
End If
With objStream
.Type = 2
.Mode = 3
.Open
.LoadFromFile Server.MapPath(File)
If Err.Number<>0 Then
Response.Write " 文件"&File&"无法被打开，请检查是否存在!"
Err.Clear
Response.End
End If
.Charset = "GB2312"
.Position = 2
LoadFile = .ReadText
.Close
End With
Set objStream = Nothing
End Function[/quote]
假如读取了head.asp 和bottom.asp
那么
[quote]
savetofile (list,"index.html")就可以改为savetofile (loadfile("head.asp")&list&loadfile("bottom.asp"),"index.html")[/quote]